AkelPad

Code: Select all

'========================   Описание   =====================================
' Циклическое разбиение окна с заданной очерёдностью
' http://akelpad.sourceforge.net/forum/viewtopic.php?p=11012#p11012
'========================  Параметры =====================================
'В параметрах вызова скрипта должен быть прописан один параметр:
' 1 - Переключение горизонтальное --> вертикальное --> четыре части
' 2 - Переключение вертикальное --> горизонтальное --> четыре части
' 3 - Переключение горизонтальное --> четыре части -> вертикальное
' 4 - Переключение вертикальное --> четыре части --> горизонтальное
' 5 - Переключение четыре части --> вертикальное --> горизонтальное
' 6 - Переключение четыре части -- > горизонтальное --> вертикальное
'
' Call("Scripts::Main", 1, "SwitchSplittedWindow.vbs", `"2"`) Icon("%a\AkelFiles\Plugs\ToolBarImage.dll", 632)		'работает по установленному порядку
' Call("Scripts::Main", 1, "SwitchSplittedWindow.vbs", `"4212"`) Icon("%a\AkelFiles\Plugs\Toolbar.dll", 22)		'просто разбивает закладку файла по номеру команды
'
' Автор:            Аверин Андрей & VladSh
' Версия:          1.5 (2011.01.06 - 2011.02.16)
' Mail:               Averin-And@yandex.ru
'===========================================================
Set oSet = AkelPad.ScriptSettings()

If WScript.Arguments.Count < 1 Then
	Param = 1		' если порядок не задан в аргументах, то по умолчанию работает 1-й вариант: гор -> верт -> 4 части
Else
	Param = CInt(WScript.Arguments(0))
End If

If Param <= 6 Then
	Select Case Param
		Case 1
			Call Switch(4214, 4213, 4212)
		Case 2
			Call Switch(4213, 4214, 4212)
		Case 3
			Call Switch(4214, 4212, 4213)
		Case 4
			Call Switch(4213, 4212, 4214)
		Case 5
			Call Switch(4212, 4213, 4214)
		Case 6
			Call Switch(4212, 4214, 4213)
	End Select
Else
	Call SplitWindow(Param)
End If


Sub Switch(n, m, k)
	Do
		Name = GetHandleCurrent()
		
		If Name = 0 Then
			Call SplitWindow(n)
			Call OptionWrite(GetHandleCurrent(), n)
		Else
			l = CInt(OptionRead(Name))
			Select Case l
			Case 0
				l = n
			Case n
				l = m
			Case m
				l = k
			Case k
				Call SplitWindow(4214)
				Call OptionDelete(Name)
				Exit Do
			End Select
			Call SplitWindow(l)
			Call SplitWindow(l)
			Call OptionWrite(Name, l)
		End If
		
		Exit Do
	Loop
	
	Call oSet.End()
End Sub

Function GetHandleCurrent()
	GetHandleCurrent = AkelPad.SendMessage(AkelPad.GetEditWnd(), 3447, 0, 0)
End Function

Sub OptionWrite(sOptionName, nOptionValue)
	Call oSet.Begin(WScript.ScriptBaseName, &H2)		'POB_SAVE
	Call oSet.Write(sOptionName, 1, nOptionValue)		'PO_DWORD
End Sub

Function OptionRead(sOptionName)
	Call oSet.Begin(WScript.ScriptBaseName, &H1)		'POB_READ
	OptionRead = oSet.Read(sOptionName, 1)		'PO_DWORD
End Function

Sub OptionDelete(sOptionName)
	Call oSet.Begin(WScript.ScriptBaseName, &H2)		'POB_SAVE
	Call oSet.Delete(sOptionName)
End Sub

Sub SplitWindow(n)
	Call AkelPad.SendMessage(AkelPad.GetMainWnd(), 273, n, 0)
End Sub